← Dokumentace WAF / managed-rules / check-for-exposed-credentials

Konfigurace kontrol odhalených přihlašovacích údajů pomocí Terraformu

Následující ukázková konfigurace Terraform řeší běžný případ použití kontrol uniklých přihlašovacích údajů.

Další informace naleznete v Dokumentace Terraform Cloudflare provider ↗.

Pokud používáte Cloudflare API, přečtěte si Konfigurace kontrol odhalených přihlašovacích údajů přes API.

Přidat vlastní pravidlo pro kontrolu odhalených přihlašovacích údajů

Následující konfigurace vytvoří vlastní sadu pravidel s jediným pravidlem, které kontroly odhalených přihlašovacích údajů.

Kontroly odhalených přihlašovacích údajů můžete přidat pouze k pravidlům ve vlastní sadě pravidel (tedy sadě pravidel s kind = "custom").

resource "cloudflare_ruleset" "account_firewall_custom_ruleset_exposed_creds" {
  account_id  = "<ACCOUNT_ID>"
  name        = "Custom ruleset checking for exposed credentials"
  description = ""
  kind        = "custom"
  phase       = "http_request_firewall_custom"

  rules {
    ref         = "check_for_exposed_creds_add_header"
    description = "Add header when there is a rule match and exposed credentials are detected"
    expression  = "http.request.method == \"POST\" && http.request.uri == \"/login.php\""
    action      = "rewrite"
    action_parameters {
      headers {
        name      = "Exposed-Credential-Check"
        operation = "set"
        value     = "1"
      }
    }
    exposed_credential_check {
      username_expression = "url_decode(http.request.body.form[\"username\"][0])"
      password_expression = "url_decode(http.request.body.form[\"password\"][0])"
    }
  }
}

Chcete-li vytvořit další pravidlo, přidejte nové rules objekt do stejného cloudflare_ruleset prostředek.

Následující konfigurace nasadí vlastní sadu pravidel. Definuje závislost na account_firewall_custom_ruleset_exposed_creds prostředek a získá ID vytvořené vlastní sady pravidel:

resource "cloudflare_ruleset" "account_firewall_custom_entrypoint" {
  account_id  = "<ACCOUNT_ID>"
  name        = "Account-level entry point ruleset for the http_request_firewall_custom phase deploying a custom ruleset checking for exposed credentials"
  description = ""
  kind        = "root"
  phase       = "http_request_firewall_custom"

  depends_on = [cloudflare_ruleset.account_firewall_custom_ruleset_exposed_creds]

  rules {
    ref         = "deploy_custom_ruleset_example_com"
    description = "Deploy custom ruleset for example.com"
    expression  = "(cf.zone.name eq \"example.com\")"
    action      = "execute"
    action_parameters {
      id = cloudflare_ruleset.account_firewall_custom_ruleset_exposed_creds.id
    }
  }
}

Další zdroje

Další příklady konfigurace Terraformu najdete v Konfigurace vlastních pravidel WAF pomocí Terraformu.